엑셀 VLOOKUP 2번째 값 구하기 공식 (n번째 값 찾기)

VLOOKUP 함수로 2번째 위치한 값을 구하는 공식의 사용법과 단계별 동작원리를 알아봅니다.

홈페이지 » 엑셀 VLOOKUP 두번째 값 구하기 공식 (n번째 값 찾기)

엑셀 VLOOKUP 두번째 값 구하기 공식

엑셀 VLOOKUP함수 두번째 값 구하기 목차 바로가기
함수 공식
{ =INDEX($출력범위,SMALL(IF($찾을값=$찾을범위,ROW($찾을범위)-ROW($시작셀)+1),N번째)) }

본 공식은 배열수식이므로 Microsoft 365 이전버전 사용자는 Ctrl + Shift + Enter 로 입력합니다.

인수 설명
엑셀 VLOOKUP 2번째 값 구하기 공식 인수_R
VLOOKUP 함수 2번째 값 구하기 공식에 사용되는 인수
인수설명
출력범위VLOOKUP 함수로 출력할 값이 입력된 범위입니다.
찾을값VLOOKUP 함수로 찾을 값입니다.
찾을범위찾을값이 입력된 범위입니다.
시작셀찾을 범위(또는 출력범위)의 시작셀입니다.
N번째몇번째 있는 값을 찾을 것인지 숫자로 입력합니다. (예: 1, 2, 3 ... )

예제파일 다운로드

호환성
운영체제호환성
Windows 버전모든 엑셀 버전에서 사용 가능합니다.
Mac 버전모든 엑셀 버전에서 사용 가능합니다.
사용된 기초 함수
선택한 범위에서 원하는 위치의 값을 반환합니다.
입력한 조건의 참/거짓을 판단하여 값을 반환합니다.

엑셀 VLOOKUP함수 두번째 값 구하기 공식 알아보기

공식 설명

본 공식은 VLOOKUP 함수로 n 번째 있는 값을 검색하는 VLOOKUP 함수 두번째 값 구하기 공식입니다. 찾을값의 중복된 개수에 상관없이 2번째, 3번째.. 이상의 값도 검색가능합니다. 본 공식은 배열수식이므로 Microsoft 365 이전버전 사용자는 Ctrl + Shift + Enter로 수식을 입력해야 합니다.

VLOOKUP 함수로 여러개의 값을 반환하려면 VLOOKUP 여러개 값 출력하기 공식을 사용합니다.

공식의 동작원리
  1. 출력범위의 개수만큼 1부터 증가하는 순번을 반환합니다. (ROW 함수 사용)
    =ROW(D8:D12)-ROW(D8)+1
    ={8,9,10,11,12}-8+1
    ={1,2,3,4,5}
  2. 찾을범위의 값이 찾을값과 일치할 경우 순번을 반환합니다. (IF 함수 사용)
    =IF("사과"={"사과","배","사과","귤","사과"},ROW(D8:D12)-ROW(D8)+1)
    =IF("사과"={"사과","배","사과","귤","사과"},{1,2,3,4,5})
    ={1,FALSE,3,FALSE,5}
  3. 반환된 순번에서 n번째로 작은 값을 반환합니다. (SMALL 함수 사용)
    =SMALL(IF($찾을값=$찾을범위,ROW($찾을범위)-ROW($시작셀)+1),N번째)
    =SMALL({1,FALSE,3,FALSE,5},2)
    =3 '순번에서 2번째로 작은 값인 3을 반환합니다.
  4. 출력범위의 n값을 반환합니다. (INDEX 함수 사용)
    =INDEX($출력범위,SMALL(IF($찾을값=$찾을범위,ROW($찾을범위)-ROW($시작셀)+1),N번째))
    =INDEX({10,20,30,40,50},3)
    =30 '출력범위의3번째 값인 30을 반환합니다.
5 1 vote
게시글평점
현재 페이지 댓글알림 신청
알림 설정
guest
2 Comments
Inline Feedbacks
View all comments
wngmal@naver.com
2020년 8월 28일 4:43 오후
게시글평점 :
     

함수 마스터 가즈아!

yim****
yim****
2020년 10월 17일 7:55 오전
게시글평점 :
     

감사합니다

2
0
여러분의 생각을 댓글로 남겨주세요.x