엑셀 VBA 마지막 셀 찾기 (마지막 행·열 번호 구하기)

바로 쓰는 코드

대부분의 상황에서는 UsedRange 로 충분합니다.

'// 시트에서 사용된 전체 범위의 마지막 셀
With ThisWorkbook.Worksheets("시트명")
    Dim endRow As Long   '// 마지막 행
    Dim endCol As Long   '// 마지막 열
    endRow = .UsedRange.Rows.Count + .UsedRange.Row - 1
    endCol = .UsedRange.Columns.Count + .UsedRange.Column - 1
End With

특정 열이나 행 하나만 볼 때는 End 속성을 씁니다.

'// A열의 마지막 행 / 1행의 마지막 열
With ThisWorkbook.Worksheets("시트명")
    Dim endRow As Long
    Dim endCol As Long
    endRow = .Cells(.Rows.Count, 1).End(xlUp).Row
    endCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
End With

사용 예제

마지막 셀의 주소와 행·열 번호를 메시지 상자로 보여 주는 명령문입니다.

Sub Print_FinalCell()

    Dim sShtName As String
    sShtName = "시트1"   '// 시트명을 입력합니다.

    With ThisWorkbook.Worksheets(sShtName)
        Dim endRow As Long
        Dim endCol As Long
        Dim endCell As String
        endRow = .UsedRange.Rows.Count + .UsedRange.Row - 1
        endCol = .UsedRange.Columns.Count + .UsedRange.Column - 1
        endCell = .Cells(endRow, endCol).Address
    End With

    MsgBox sShtName & "의 마지막 셀은 " & endCell & "입니다." & vbNewLine & _
           "행 번호는 " & endRow & ", 열 번호는 " & endCol & "입니다."

End Sub

동작 원리 1 — End 속성은 Ctrl + Shift + 방향키입니다

Range.End 는 시트에서 Ctrl + Shift + 방향키를 누른 것과 같습니다. 기준 셀에서 값이 이어진 마지막 셀까지 건너뜁니다.

맨 아래 행에서 xlUp 으로 거슬러 올라오는 이유는, 중간에 빈 셀이 있어도 진짜 마지막 값에 닿기 때문입니다.

동작 원리 2 — UsedRange 는 사용된 전체 범위입니다

시트1의 B2:C14 를 썼다면 이렇게 동작합니다.

Set rng = ThisWorkbook.Worksheets("시트1").UsedRange
'// B2:C14 범위를 돌려줍니다.

endRow = rng.Rows.Count    '// 사용된 행의 개수 → 13
startRow = rng.Row         '// 범위가 시작되는 행 번호 → 2

endRow + startRow - 1      '// 13 + 2 - 1 = 14 (마지막 행 번호)

행 개수와 시작 위치를 더한 뒤 1을 빼는 이유는, 개수는 1부터 세지만 번호는 시작 행부터 세기 때문입니다. 열도 같은 원리입니다.

동작 원리 3 — Rows.Count 로 시트 크기를 받아옵니다

시트가 가질 수 있는 행·열 개수는 버전마다 다릅니다.

참고 문서

• Range.End 속성 — Microsoft Learn
• Worksheet.UsedRange 속성 — Microsoft Learn