엑셀 툴바 숨기거나 보이는 방법 :: HideToolbar/ShowToolbar 명령문

실행 중인 엑셀 파일의 툴바를 숨기는 HideToolBar 매크로 명령문의 사용법과 동작원리를 살펴봅니다.

홈페이지 » 엑셀 툴바 숨기거나 보이는 방법 :: Hide/ShowToolbar 명령문

엑셀 툴바 숨기기 :: HideToolbar/ShowToolbar 명령문 사용법

엑셀 HideToolbar/ShowToolbar 명령문 목차 바로가기
요약

엑셀 Hide/ShowToolbar 함수는 실행 중인 엑셀 파일의 리본 버튼을 숨기거나 보여주는 VBA 명령문입니다.

엑셀 툴바 숨기기 예제_R
엑셀 리본/툴바를 완전히 숨길 수 있습니다.
명령문 구문
Hide/ShowToolbar ( [전체화면] )
사용된 인수 및 변수 알아보기
인수설명
전체화면
[선택인수, Boolean]
True일 경우 툴바를 숨김과 동시에 엑셀이 전체화면으로 변경됩니다. 기본값은 False 입니다. (HideToolbar에만 사용합니다.)

예제파일 다운로드

상세 설명

엑셀 Hide/ShowToolbar 함수는 실행 중인 엑셀 파일의 리본 버튼을 숨기거나 보여주는 VBA 명령문입니다. 제작한 엑셀 서식을 다른 사용자가 편집하지 못하도록 보호하거나 보안상의 이유로 시트 내 다른 자료의 편집을 제한해야 할 경우 사용할 수 있습니다.

본 명령문을 복사하여 VBA 편집기의 '삽입 - 모듈' 로 새로울 모듈을 추가하여 모듈 안에 붙여넣기 하신 뒤, 현재_통합_문서의 통합문서 이벤트와 활용하는 것이 더욱 효율적입니다.

현재_통합_문서의 WorkBook_Open 이벤트 (통합문서 실행시) 와 WorkBook_WindowActivate 이벤트 (통합문서 활성화시) 에 함수를 사용하면 외부 매크로로 툴바를 보이게 하더라도, 파일이 활성화 될 때마다 툴바가 숨겨지므도 다른 사용자가 파일 내 다른 자료를 편집하지 못하도록 제한할 수 있습니다.

실전 사용 예제
  1. 파일 실행 시 툴바를 숨기는 방법
    Private Sub Workbook_Open()
        HideToolbar
    End Sub
  2. 다른 파일에서 현재 파일로 활성화 될 때 툴바를 숨기는 방법
    Private Sub Workbook_WindowActivate(ByVal Wn As Window)
        HideToolbar
    End Sub

엑셀 리본/툴바 보이기 숨기기 명령문 Hide/ShowToolbar 명령문 동작원리

HideToolbar/ShowToolbar 명령문 전체 코드
Sub HideToolbar(Optional FullScreen As Boolean = False)
 
With Application
    .ExecuteExcel4Macro "show.toolbar(""Ribbon"",False)"
    .DisplayFullScreen = FullScreen
End With
 
End Sub
 
Sub ShowToolbar()
 
With Application
If .DisplayFullScreen = True Then
    .ScreenUpdating = False
    .DisplayFullScreen = False
    .ExecuteExcel4Macro "show.toolbar(""Ribbon"",True)"
    .WindowState = xlMaximized
    .ScreenUpdating = True
Else
    .ExecuteExcel4Macro "show.toolbar(""Ribbon"",True)"
End If
End With
 
End Sub
명령문 동작원리 단계별 알아보기
  1. 엑셀 Application 을 With 문으로 묶어줍니다.
    With Application
       '실행할 명령문
    End With
  2. ExecuteExcel4Macro (Excel4.0매크로) 를 통해 툴바가 완전히 보이지 않도록 숨겨줍니다.
    .ExecuteExcel4Macro "show.toolbar(""Ribbon"",False)"
  3. DisplayFullScreen 속성을 사용하여 엑셀 화면을 툴바가 없는 전체화면으로 변경합니다.
    .DisplayFullScreen = FullScreen

관련링크 : MS홈페이지 ExecuteExcel4Marco 함수 상세설명

현재 페이지 댓글알림 신청
알림 설정
guest
0 Comments
Inline Feedbacks
View all comments
0
여러분의 생각을 댓글로 남겨주세요.x