엑셀 주번호 날짜 변환 공식 :: 함수 예제

주번호를 참고하여 해당주의 시작일/종료일을 계산하는 엑셀 함수 공식을 알아봅니다.

홈페이지 » 엑셀 주번호 날짜 변환 공식 :: 함수 예제

엑셀 주번호 날짜 변환 공식 공식

엑셀 주번호 날짜 변환 공식 목차 바로가기
함수 공식

시작일

=MAX(DATE(년도,1,1),DATE(년도,1,1)-WEEKDAY(DATE(년도,1,1),기준요일)+(주번호-1)*7+1)

종료일

=MIN(DATE(년도+1,1,0),DATE(년도,1,1)-WEEKDAY(DATE(년도,1,1),기준요일)+주번호*7)
인수 설명
엑셀 주번호 날짜 변환 공식
엑셀 주 번호 날짜 변환 공식 예제
인수 설명
년도 주번호로 날짜를 계산할 기준년도입니다.
주번호 주번호입니다.
기준요일 주번호로 날짜를 계산할 기준요일입니다. 기본값(월~일)로 계산할 경우 11을 사용합니다.
  • 11(기본) : 월~일
  • 12 : 화~월
  • 13 : 수~화
  • 14 : 목~수
  • 15 : 금~목
  • 16 : 토~일
  • 17 : 일~월
호환성
운영체제 호환성
Windows 버전 모든 엑셀 버전에서 사용 가능합니다.
Mac 버전 모든 엑셀 버전에서 사용 가능합니다.

예제파일 다운로드

오빠두엑셀의 강의 예제파일은 여러분을 위해 자유롭게 제공하고 있습니다.

  • [엑셀공식] 주번호 날짜 변환 공식
    예제파일

엑셀 주번호 날짜 변환 공식 공식 알아보기

공식 설명

각 년도의 1월 1일부터 12월 31일까지 1주~52주(또는 ~54주)까지 계산된 주 번호를 참고하여 각 주의 시작일과 종료일을 계산하는 주단위 날짜 변환 공식입니다.

엑셀의 WEEKNUM 함수를 사용하면 특정 날짜의 년도기준(1주~52주) 주번호를 손쉽게 계산할 수 있습니다.또한 상황에 따라 월별/요일별로 주번호를 계산해야 할 경우에는 아래 게시글에 적어드린 공식을 사용합니다.

실무에서 대부분 사용되는 월요일~일요일 기준으로 주번호→날짜를 계산할 경우, 기준요일 값으로 11을 사용하며, 일요일~월요일 기준으로 계산할 시 기준요일은 17을 사용합니다.

공식의 동작원리
  1. 각 년도의 1월 1일의 요일번호를 '기준요일' 기준으로 계산합니다.
    =WEEKDAY(DATE(년도,1,1),기준요일)
    =WEEKDAY(DATE(2022,1,1),11)
    =6 '2022년 1월 1일은 토요일입니다. (월~일 기준 6번째)
  2. 각 년도의 1월 1일을 포함하는 주의 시작요일을 계산합니다.
    =DATE(2022,1,1)-WEEKDAY(DATE(2022,1,1),11)+1
    ='2022/1/1'-6+1
    ='2021/12/27'
  3. 1월 1일이 1주차로 시작되므로, 각 주번호에서 1을뺀 뒤 7을 곱한 값을 더해서 시작요일을 계산합니다.
    =DATE(2022,1,1)-WEEKDAY(DATE(2022,1,1),11)+1+(3-1)*7
    ='2021/12/27' + 2*7
    ='2022/1/10'  '2022년 3주차의 시작일은 1월 10일입니다.
  4. MAX 함수로 1주차의 시작일이 1/1보다 작을 경우, 1/1을 반환합니다.
    =MAX(DATE(2022,1,1),DATE(2022,1,1)-WEEKDAY(DATE(2022,1,1),11)+(1-1)*7+1)
    =MAX('2022/1/1','2021/12/27')
    ='2022/1/1' '1주차일 경우 시작일이 1/1보다 작으므로, 1/1을 반환합니다.
5 1 투표
게시글평점
guest
1 댓글
Inline Feedbacks
모든 댓글 보기
오진짱
Member
오진짱(@opopohjinnaver-com)
2022년 1월 16일 6:23 오후
게시글평점 :
     

감사합니다

1
0
여러분의 생각을 댓글로 남겨주세요.x