엑셀 범위 내 단어 검색 :: 엑셀 함수 공식

넓은 범위 안에서 검색한 단어의 셀 주소를 반환하는 공식의 동작원리와 사용법을 알아봅니다.

홈페이지 » 엑셀 범위 내 단어 검색 :: 엑셀 함수 공식

엑셀 범위 내 단어 검색 공식

엑셀 범위 내 단어 검색 목차 바로가기
함수 공식
=ADDRESS(MIN(IF(범위=단어,ROW(범위))),MIN(IF(범위=단어,COLUMN(범위))))
'배열수식이므로 엑셀 2021 / M365 이전 버전 사용자는 Ctrl + Shift + Enter로 입력합니다.
인수 설명
인수 설명
범위 단어를 검색할 범위입니다.
단어 검색할 단어입니다.

예제파일 다운로드

오빠두엑셀의 강의 예제파일은 여러분을 위해 자유롭게 제공하고 있습니다.

  • [엑셀공식] 넓은 범위 단어 검색 공식
    예제파일

호환성
운영체제 호환성
Windows 버전 모든 엑셀 버전에서 사용 가능합니다.
Mac 버전 모든 엑셀 버전에서 사용 가능합니다.
사용된 기초 함수

엑셀 넓은 범위 단어 검색 공식 알아보기

공식 설명

넓은 범위 내에서 검색한 단어의 셀 주소를 반환하는 공식입니다. 본 공식은 배열수식이므로 엑셀 2021 및 M365 이전 버전 사용자는 Ctrl + Shift + Enter로 수식을 입력해야 합니다.

본 공식은 VLOOKUP 및 INDEX/MATCH 함수의 다양한 응용 공식을 작성할 때 활용할 수 있습니다. 이를 활용한 찾기(Ctrl + F) 자동화 공식의 동작원리 및 사용법은 아래 영상강의를 참고해주세요.

공식의 동작원리
  1. ROW 함수를 사용해 범위의 행번호가 나열된 배열을 만듭니다.
    =ROW(B7:D10)
    ={7,8,9,10}
  2. IF 함수를 사용해 만약 범위 안의 값이 단어와 같을 경우, 해당 셀의 행번호를 출력합니다. 
    =IF(B7:D10=G7,ROW(B7:D10))
    =IF({"사과","키위","파인애플",...}="사과",{7,8,9,10})
    ={7,FALSE,FALSE,FALSE,FALSE,...}
  3. MIN 함수로 배열 내 최소값을 계산합니다.
    =MIN(IF(B7:D10=G7,ROW(B7:D10)))
    =MIN({7,FALSE,FALSE,FALSE,...})
    =7
  4. 동일한 원리로 검색한 단어의 열 번호를 계산합니다.
    =MIN(IF(B7:D10=G7,COLUMN(B7:D10)))
    =MIN({2,FALSE,FALSE,...})
    =2
  5. ADDRESS 함수의 계산된 행/열번호의 셀 주소를 반환합니다.
    =ADDRESS(MIN(IF(B7:D10=G7,ROW(B7:D10))),MIN(IF(B7:D10=G7,COLUMN(B7:D10))))
    =ADDRESS(7,2)
    ="$B$7"
0 0 투표
게시글평점
guest
0 댓글
Inline Feedbacks
모든 댓글 보기
0
여러분의 생각을 댓글로 남겨주세요.x