엑셀 마지막 단어 제거 쉬운 방법 :: 엑셀 함수 공식

공식을 사용하여 문장의 마지막 단어를 손 쉽게 제거하는 방법과 공식의 동작원리를 살펴봅니다.

홈페이지 » 엑셀 마지막 단어 제거 쉬운 방법 :: 엑셀 함수 공식

엑셀 마지막 단어 제거 공식

엑셀 마지막 단어 제거 목차 바로가기
함수 공식
=MID(셀,1,FIND("|",SUBSTITUTE(셀," ","|",LEN(셀)-LEN(SUBSTITUTE(셀," ",""))))-1)
인수 설명
엑셀 마지막 단어 제거 공식 인수_R
엑셀 마지막 단어 제거 공식에 사용된 인수
인수 설명
마지막 단어를 제거할 문장이 입력된 셀 또는 문장을 입력합니다.

예제파일 다운로드

호환성
운영체제 호환성
Windows 버전 모든 엑셀 버전에서 사용 가능합니다.
Mac 버전 모든 엑셀 버전에서 사용 가능합니다.
사용된 기초 함수
문자열의 특정 위치부터 원하는 문자수만큼의 텍스트를 반환합니다.
선택된 셀 또는 문자열의 글자수를 셉니다.

엑셀 마지막단어 제거 공식 알아보기

공식 설명

본 공식은 문장의 마지막 단어를 찾아 제거하는 엑셀 함수 공식입니다. 문장의 마지막 띄어쓰기 이후 사용된 단어를 찾아 제거합니다.

문장에 세로막대기호("|")가 사용된 경우 마지막 단어가 올바르게 제거되지 않으므로, 문장에 세로막대기호가 사용된 경우 공식의 세로막대기호를 다른 특수기호(예: ~, *)로 바꿔서 사용합니다.

=MID(셀,1,FIND("*",SUBSTITUTE(셀," ","*",LEN(셀)-LEN(SUBSTITUTE(셀," ",""))))-1)
공식의 동작원리
  1. LEN 함수와 SUBSTITUE 함수로 문장에 사용된 띄어쓰기 개수를 계산합니다.
    =LEN("나 보기가 역겨워 가실 때에는")-LEN(SUBSTITUTE("나 보기가 역겨워 가실 때에는"," ",""))
    =LEN("나 보기가 역겨워 가실 때에는")-LEN("나보기가역겨워가실때에는")
    =16-12
    =4
  2. SUBSTITUTE 함수로 마지막 띄어쓰기를 특수기호로 변경합니다.
    =SUBSTITUTE(셀," ","|",LEN(셀)-LEN(SUBSTITUTE(셀," ",""))))-1)
    =SUBSTITUTE("나 보기가 역겨워 가실 때에는"," ","|",4)
    ="나 보기가 역겨워 가실|때에는"
  3. FIND 함수로 문장 안에서 특수기호가 위치한 순번을 계산합니다.
    =FIND("|",SUBSTITUTE(셀," ","|",LEN(셀)-LEN(SUBSTITUTE(셀," ",""))))
    =FIND("|","나 보기가 역겨워 가실|때에는")
    =13
  4. MID 함수로 마지막 띄어쓰기 이전까지 단어를 추출합니다.
    =MID(셀,1,FIND("|",SUBSTITUTE(셀," ","|",LEN(셀)-LEN(SUBSTITUTE(셀," ",""))))-1)
    =MID("나 보기가 역겨워 가실 때에는",1,13-1)
    =MID("나 보기가 역겨워 가실 때에는",1,12)
    ="나 보기가 역겨워 가실"

관련 링크 : MS 홈페이지 SUBSTITUTE 함수 사용법

guest
0 댓글
Inline Feedbacks
모든 댓글 보기
0
여러분의 생각을 댓글로 남겨주세요.x