엑셀 괄호 안 텍스트 추출 공식
지원 버전 자세히 보기
문자열의 괄호 안 텍스트를 추출하는 공식입니다. 괄호 쌍이 여러 개일 때는 시작 위치나 발생 번호를 지정해 원하는 괄호를 추출할 수 있습니다.
인수 설명
01첫 번째 괄호 안 추출
=MID ( 셀, FIND ( "(", 셀 ) + 1, FIND ( ")", 셀, FIND ( "(", 셀 ) + 1 ) - FIND ( "(", 셀 ) - 1 )인수 설명 자세히 보기(인수를 클릭하면 해당 영역만 강조됩니다. 여러 개를 함께 켜고 끌 수 있습니다.)
02시작 위치를 지정해 추출
=MID ( 셀, FIND ( "(", 셀, 시작위치 ) + 1, FIND ( ")", 셀, 시작위치 ) - FIND ( "(", 셀, 시작위치 ) - 1 )인수 설명 자세히 보기
03몇 번째 괄호인지 지정해 추출 (엑셀 2024 · M365)
=TEXTBEFORE ( TEXTAFTER ( 셀, "(", 발생번호 ), ")" )인수 설명 자세히 보기
동작 원리
01첫 번째 괄호 안 추출
FIND 함수는 괄호 위치를 계산하고 MID 함수는 두 위치 사이의 텍스트를 반환합니다.
첫 번째 괄호 기본 공식의 예제 시트에서 E2 셀이 220V를 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
FIND 함수가 여는 괄호 위치를 찾습니다
FIND 함수는 A2에서 첫 번째 여는 괄호의 위치인 6을 반환합니다.
=FIND ( "(", A2 )
= 6
여는 괄호의 문자 위치입니다. FIND 함수가 닫는 괄호 위치를 찾습니다
여는 괄호 다음 위치부터 닫는 괄호를 찾으면 11을 반환합니다.
=FIND ( ")", A2, FIND ( "(", A2 )+1 )
= 11
닫는 괄호의 문자 위치입니다. MID 함수가 괄호 사이를 반환합니다
MID 함수는 여는 괄호 다음인 7번째 문자부터 네 글자를 반환합니다.
=MID ( A2, 6+1, 11-6-1 )
= "220V"
첫 번째 괄호 안의 텍스트입니다. 02시작 위치를 지정해 추출
두 FIND 함수가 같은 시작 위치에서 다음 여는 괄호와 닫는 괄호를 찾고 MID 함수가 그 사이를 반환합니다.
시작 위치 지정 공식의 예제 시트에서 F3 셀이 역삼을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
FIND 함수가 다음 여는 괄호를 찾습니다
A3의 7번째 문자부터 검색하면 두 번째 여는 괄호가 있는 11을 반환합니다.
=FIND ( "(", A3, B3 )
= 11
두 번째 여는 괄호의 문자 위치입니다. FIND 함수가 다음 닫는 괄호를 찾습니다
닫는 괄호도 같은 B3 위치부터 검색하므로 두 번째 닫는 괄호가 있는 14를 반환합니다.
=FIND ( ")", A3, B3 )
= 14
두 번째 닫는 괄호의 문자 위치입니다. MID 함수가 지정한 괄호 사이를 반환합니다
MID 함수는 12번째 문자부터 두 글자를 반환해 두 번째 괄호 안의 텍스트를 추출합니다.
=MID ( A3, 11+1, 14-11-1 )
= "역삼"
두 번째 괄호 안의 텍스트입니다. 03몇 번째 괄호인지 지정해 추출 (엑셀 2024 · M365)
TEXTAFTER 함수는 지정한 여는 괄호 뒤를 남기고 TEXTBEFORE 함수는 다음 닫는 괄호 앞까지만 반환합니다.
엑셀 2024 · M365 최신 공식의 예제 시트에서 G3 셀이 역삼을 반환하는 계산 과정입니다. 단계마다 강조된 부분이 어떻게 계산되는지 살펴보세요.
TEXTAFTER 함수가 지정한 괄호 뒤를 남깁니다
C3의 발생 번호 2를 사용하면 두 번째 여는 괄호 뒤의 텍스트만 남습니다.
=TEXTAFTER ( A3, "(", C3 )
= "역삼)"
두 번째 여는 괄호 뒤에 남은 텍스트입니다. TEXTBEFORE 함수가 닫는 괄호 앞을 반환합니다
TEXTBEFORE 함수는 남은 텍스트에서 닫는 괄호 앞의 두 글자만 반환합니다.
=TEXTBEFORE ( "역삼)", ")" )
= "역삼"
두 번째 괄호 안의 텍스트입니다. ![[도구 업데이트] 실시간 추첨, 무료 도구 업데이트!](https://www.oppadu.com/wp-content/uploads/2026/09/마블레이스-런칭.png)
![[직원 채용] 오빠두엑셀이 정규직 동료를 모십니다](https://www.oppadu.com/wp-content/uploads/2026/08/직원-채용-1_R.png)
![[도구 업데이트] 투명 인감 도장 PNG를 만들어보세요!](https://www.oppadu.com/wp-content/uploads/2026/09/투명-도장-생성기-안내.png)
혹시 이 함수로 숫자를 추출하면 sum함수는 안 먹히나요?? 셀+셀+셀 이렇게하면 합계가 나오는데 sum함수는 합계가 안 보이네요 ㅠ
라고 사용해도 똑같은 결과가 나오게 됩니다.
=MID(B8,FIND("(",B8)+1,FIND(")",B8,FIND("(",B8)+1)-FIND("(",B8)-1)
중간의 FIND("(",B8)+1 한 번 더 사용한 이유를 잘 해석이 안되어서요..
어떤 기능이 있는 것인가요.. ?
따라서, 기호가 여러개 있을 경우 n번째 위치한 "(" 기호의 다음 위치부터 "(" 기호를 검색하도록 FIND + 1 사용합니다.
항상 감사드립니다.
여러 방법이 있지만, 가장 간단한 방법으로 substitute 함수를 활용해보시길 바랍니다.
동일한 원리로
로 ml를 지울 수 있습니다. 또는 아래 링크에 숫자만 추출하는 공식을 활용하는 방법도 있으니 한번 확인해보세요.
엑셀 셀에서 숫자만 추출하는 방법 :: 엑셀 공식 - 오빠두엑셀 (oppadu.com)
감사합니다.
아래와 같은 방식으로 셀하나에 글이 작성되어 있습니다
셀에 글이 작성된 시간이 "()" 괄호로 들어가 있는데요
예제 :
달 빛이 선명할수록 어둠은 더 깊어 졌다(2024-05-17 09:01:26)
하지만 정신은 오히려 또렷해 졌다(2024-05-17 09:01:30)
특정단어가 작성된 시간을 불러 오고 싶을 때는 어떻게 하면 좋을까요
"정신" 이라는 단어가 작성된 시간(2024-05-17 09:01:30)을 분리하고 싶음
먼저 =VLOOKUP("*정신*",범위,1,0) 으로 정신을 포함하는 셀을 검색한 후, 아래 공식을 사용하여 괄호 안의 날짜를 추출해보세요.
감사합니다.